Справочник MQL4 Строковые функции StringAdd

StringAdd

Присоединяет к концу строки по месту указанную подстроку.

bool  StringAdd(
   string&  string_var,        // строка, к которой добавляем
   string   add_substring      // добавляемая строка
   );

Параметры

string_var

[in][out] Строка, которая будет дополнена.

add_substring

[in] Строка, которая будет добавлена в конец исходной строки.

Возвращаемое значение

В случае успешного выполнения возвращает true, иначе false. Для получения кода ошибки нужно вызвать функцию GetLastError().

Пример:

void OnStart()
  {
//---
   long length=10000000;
   string a="a",b="b",c;
//--- первый способ
   uint starttime=GetTickCount(),finishtime;
   long i;
   for(i=0;i<length;i++)
     {
      c=a+b;
     }
   finishtime=GetTickCount();
   Print("time for 'c = a + b' = ",(finishtime-starttime)," milliseconds, i = ",i);

//--- второй способ
   starttime=GetTickCount();
   for(i=0;i<length;i++)
     {
      StringAdd(a,b);
     }
   finishtime=GetTickCount();
   Print("time for 'StringAdd(a,b)' = ",(finishtime-starttime)," milliseconds, i = ",i);

//--- третий способ
   starttime=GetTickCount();
   a="a"; // заново инициализируем переменную a
   for(i=0;i<length;i++)
     {
      c=StringConcatenate(a,b);
     }
   finishtime=GetTickCount();
   Print("time for 'c=StringConcatenate(a,b)' = ",(finishtime-starttime)," milliseconds, i = ",i);
  }

Смотри также

StringConcatenate()

Строковые функцииStringBufferLen